amibroker

Home ▸ Knowledge Base

January 20, 2016

Number of stopped-out trades as a custom metric

For the purpose of counting trades closed by particular stop we can refer to ExitReason property of the trade object in the custom backtester. The custom backtest formula presented below iterates through the list of closed trades, then counts the trades, which indicate exit reason = 2, that is stop-loss.

The following values are used for indication of the particular exit reason:

  1. normal exit
  2. maximum loss stop
  3. profit target stop
  4. trailing stop
  5. n-bar stop
  6. ruin stop (losing 99.96% of entry value)
SetCustomBacktestProc( "" );

/* Now custom-backtest procedure follows */
if( Status( "action" ) == actionPortfolio )
{
    bo = GetBacktesterObject();

    bo.Backtest(); // run default backtest procedure

    // initialize counter
    stoplossCountLong = stoplossCountShort = 0;

    // iterate through closed trades
    for( trade = bo.GetFirstTrade(); trade; trade = bo.GetNextTrade() )
    {

      // check for stop-loss exit reason
        if( trade.ExitReason == 2 )
        {
         // increase long or short counter respectively
            if( trade.IsLong() )
                stoplossCountLong++;
            else
                stoplossCountShort++;
        }
    }

   // add the custom metric
    bo.AddCustomMetric( "Stoploss trades", stoplossCountLong + stoplossCountShort,
                         stoplossCountLong, stoplossCountShort, 0 );

}

Buy = Cross( MACD(), Signal() );
Sell = Cross( Signal(), MACD() );
Short = Sell;
Cover = Buy;
ApplyStop( stopTypeLoss, stopModePercent, 2, 1 )

Related articles:

  1. Adding custom metric: Average adverse excursion
  2. Per-symbol profit/loss in a portfolio backtest
  3. Limit number of trades per day in a backtest
  4. How to display interest gains in the backtest report
  5. How to display indicator values in the backtest trade list

* Filed by Tomasz Janeczko at 3:16 pm under Custom Backtest
Comments Off on Number of stopped-out trades as a custom metric

January 6, 2015

How to display interest gains in the backtest report

The default backtest report shows total Net Profit figure, which includes both trading profits and interest earnings. With Custom Backtest procedure we can easily isolate these components by summing up profits and loses from individual trades, then subtracting trading gains from the Net Profit and report them as separate metrics.

SetCustomBacktestProc( "" );

if ( Status( "action" ) == actionPortfolio )
{
    bo = GetBacktesterObject();
    bo.Backtest(); // run default backtest procedure

    // read Net Profit, Winners and Losers profits from the report
    st = bo.GetPerformanceStats( 0 );
    netProfit = st.GetValue( "NetProfit" );
    tradeProfits = st.GetValue("WinnersTotalProfit") + st.GetValue("LosersTotalLoss");

    bo.AddCustomMetric( "Trading profits", tradeProfits );
    bo.AddCustomMetric( "Interest earnings", netProfit - tradeProfits );

}

// trading rules here
Buy = Cross( MACD(), Signal() );
Sell = Cross( Signal(), MACD() )

After backtest is run, we can see our custom metrics in the backtest report.

More information about creating custom metrics can be found in the manual:
http://www.amibroker.com/guide/a_custommetrics.html

Related articles:

  1. Per-symbol profit/loss in a portfolio backtest
  2. How to display indicator values in the backtest trade list
  3. Too small / unreadable Profit Table in the backtest report
  4. Historical portfolio backtest metrics
  5. How to add MAE / MFE dates to the backtest report

* Filed by Tomasz Janeczko at 12:18 am under Custom Backtest
Comments Off on How to display interest gains in the backtest report

October 23, 2014

How to exclude top ranked symbol(s) in rotational backtest

Rotational trading is based on scoring and ranking of multiple symbols based on user-defined criteria. For each symbol a user-definable “score” is assigned on bar by bar basis. Then, each bar, symbols are sorted according to that score and N top ranked symbols are bought, while existing positions that don’t appear in top N rank are closed.

Sometimes however, we may want to exclude the highest ranking symbol (or a couple of them) from trading. The code below shows how to do that using custom backtester.

ExcludeTopN = 1; // how many top positions to exclude
SetCustomBacktestProc("");

if ( Status( "action" ) == actionPortfolio )
{
    bo = GetBacktesterObject();
    bo.PreProcess();

    for ( bar = 0; bar < BarCount; bar++ )
    {
        Cnt = 0;
        for ( sig = bo.GetFirstSignal( bar ); sig; sig = bo.GetNextSignal( bar ) )
        {
            if ( Cnt < ExcludeTopN )
                sig.Price = -1; // exclude

            Cnt++;
        }

        bo.ProcessTradeSignals( bar );
    }

    bo.PostProcess();
}

EnableRotationalTrading( True );

SetOption( "MaxOpenPositions", 5 );
SetOption( "WorstRankHeld", 10 );
SetPositionSize( 20, spsPercentOfEquity );
PositionScore = 1 / RSI( 14 )

The code is pretty straightforward mid-level custom backtest loop but it uses one trick – setting signal price to -1 tells AmiBroker to exclude given signal from further processing. Note also that signals retrieved by GetFirstSignal / GetNextSignal are already sorted, so the highest ranked signal appears first in the list.

Related articles:

  1. Using redundant signals for entries
  2. Per-symbol profit/loss in a portfolio backtest
  3. Separate ranks for categories that can be used in backtesting
  4. How to handle delisted symbols in rotational test
  5. Handling limit orders in the backtester

* Filed by Tomasz Janeczko at 4:16 am under Custom Backtest
Comments Off on How to exclude top ranked symbol(s) in rotational backtest

October 13, 2014

Per-symbol profit/loss in a portfolio backtest

Backtesting engine in AmiBroker allows to add custom metrics to the report, both in the summary report and in the trade list. This is possible with Custom Backtester Interface, which allows to modify the execution of portfolio-level phase of the test and (among many other features) adjust report generation.

The example presented below shows how to retrieve individual profit/loss figures for each traded symbol in a portfolio test and add the results as custom metrics to the report. The code performs backtest, then iterates through the list of trades and stores each symbol profit in separate variables. Variables are created with VarSet function, which allows to build variable names dynamically, based on the symbol name. There are 2 variables generated per symbol, one holding profit for long trades and one for short trades. In the last part the code reads the created variables and adds input into the backtest report.

function ProcessTrade( trade )
{
  global tradedSymbols;
  symbol = trade.Symbol;
  //
  if( ! StrFind( tradedSymbols, "," + symbol + "," ) )
  {
    tradedSymbols += symbol + ",";
  }
  //
  // HINT: you may replace it with GetPercentProfit if you wish
  profit = trade.GetProfit();
  //
  if( trade.IsLong() )
  {
      varname = "long_" + symbol;
      VarSet( varname, Nz( VarGet( varname ) ) + profit );
  }
  else
  {
      varname = "short_" + symbol;
      VarSet( varname, Nz( VarGet( varname ) ) + profit );
  }
}
//
SetCustomBacktestProc( "" );
//
/* Now custom-backtest procedure follows */
//
if ( Status( "action" ) == actionPortfolio )
{
    bo = GetBacktesterObject();
    //
    bo.Backtest(); // run default backtest procedure
    //
    tradedSymbols = ",";
    //
    //iterate through closed trades
    for ( trade = bo.GetFirstTrade( ); trade; trade = bo.GetNextTrade( ) )
    {
        ProcessTrade( trade );
    }
    //
    //iterate through open positions
    for ( trade = bo.GetFirstOpenPos( ); trade; trade = bo.GetNextOpenPos( ) )
    {
        ProcessTrade( trade );
    }
    //
    //iterate through the list of traded symbols and generate custom metrics
    for ( i = 1; ( sym = StrExtract( tradedSymbols, i ) ) != ""; i++ )
    {
        longprofit = VarGet( "long_" + sym );
        shortprofit = VarGet( "short_" + sym );
        allprofit = Nz( longprofit ) + Nz( shortprofit );
        // metric uses 2 decimal points and
        // 3 (calculate sum) as a "combine method" for walk forward out-of-sample
        bo.AddCustomMetric( "Profit for " + sym, allprofit, longprofit, shortprofit, 2, 3 );
    }
}
//
SetOption( "MaxOpenPositions", 10 );
//
Buy = Cross( MACD(), Signal() );
Sell = Cross( Signal(), MACD() );
Short = Sell;
Cover = Buy;
SetPositionSize( 10, spsPercentOfEquity ) 

Once we run the Backtest, we will get the following output in the report, showing individual profit/loss figures for each symbol in test.

Per-symbol profit

If you prefer percent profits instead of dollar profits, just replace GetProfit() call with GetPercentProfit().

Related articles:

  1. How to display indicator values in the backtest trade list
  2. How to display interest gains in the backtest report
  3. Too small / unreadable Profit Table in the backtest report
  4. Low-level gfx example: Yearly/monthly profit chart
  5. How to exclude top ranked symbol(s) in rotational backtest

* Filed by Tomasz Janeczko at 5:12 pm under Custom Backtest
Comments Off on Per-symbol profit/loss in a portfolio backtest

March 11, 2006

How to create copy of portfolio equity?

As you know Portfolio backtester creates special ticker “~~~EQUITY” which holds portfolio-level equity of the system under test. Some may find it useful to save this equity into another symbol after backtest for future analysis and/or comparison. Good news is that it is possible to do that automatically using custom backtester procedure and AddToComposite function. The formula below shows how.
(more…)

Related articles:

  1. Historical portfolio backtest metrics
  2. Per-symbol profit/loss in a portfolio backtest
  3. How to display indicator values in the backtest trade list
  4. Re-balancing open positions
  5. How to exclude top ranked symbol(s) in rotational backtest

* Filed by Tomasz Janeczko at 2:32 pm under Custom Backtest
* 3 Comments

March 6, 2006

Re-balancing open positions

Here is an example that shows how to code rotational trading system with rebalancing. The system buys and shorts top 20 securities according to absolute value of positionscore (user definable – in this example we used 20 day rate-of-change) – each at 5% of equity then each day it rebalances existing positions to 5% if only the difference between current position value and “ideal” value is greater than 0.5% and bigger than one share.

Note that this code sample uses Custom Backtester interface that is documented here.

EnableRotationalTrading(); 

EachPosPercent = 5; 

PositionScore = ROC( C, 20 ); 

PositionSize = -EachPosPercent; 

SetOption("WorstRankHeld", 40 );
SetOption("MaxOpenPositions", 20 ); 

SetOption("UseCustomBacktestProc", True ); 

if( Status("action") == actionPortfolio )
{
  bo = GetBacktesterObject();

  bo.PreProcess(); // Initialize backtester

  for(bar=0; bar < BarCount; bar++)
  {
   bo.ProcessTradeSignals( bar );
  
   CurEquity = bo.Equity;
  
   for( pos = bo.GetFirstOpenPos(); pos; pos = bo.GetNextOpenPos() )
   {
    posval = pos.GetPositionValue();
   
    diff = posval - 0.01 * EachPosPercent * CurEquity;
    price = pos.GetPrice( bar, "C" );
   
    // rebalance only if difference between desired and
    // current position value is greater than 0.5% of equity
    // and greater than price of single share
    if( diff != 0 AND
        abs( diff ) > 0.005 * CurEquity AND
        abs( diff ) > price )
    {
     bo.ScaleTrade( bar, pos.Symbol, diff < 0, price, abs( diff ) );
    }
   }
  }
  bo.PostProcess(); // Finalize backtester

Related articles:

  1. How to exclude top ranked symbol(s) in rotational backtest
  2. How to close open positions at the end of the day (for daytraders)
  3. How to create copy of portfolio equity?
  4. Historical portfolio backtest metrics
  5. Using redundant signals for entries

* Filed by Tomasz Janeczko at 3:50 pm under Custom Backtest
Comments Off on Re-balancing open positions